ISCDOForm.Patient

Example

Display the number of the CDO forms and some information about them, including the name of the patient whose forms are loaded.

Dim aPatient
Dim aCDOFormUtils
Dim aCDOForms, aCDOForm
Dim i, j
Dim aMessage 
Dim aDataItems
Dim aItem

Set aPatient = Profile.SelectPatient
set aCDOFormUtils = Profile.CDOFormUtils
' TSCdoFormTemplateTypes_Base + TSCdoFormTemplateTypes_CEF + 
' TSCdoFormTemplateTypes_List + TSCdoFormTemplateTypes_HTML
set aCDOForms = aCDOFormUtils.LoadPatientForms(aPatient, 1 + 2 + 4 + 8) 
aMessage = "CDO Forms (Count = " & aCDOForms.Count & "):"
for i = 0 to aCDOForms.Count - 1
  set aCDOForm = aCDOForms.Item(i) 
  aMessage = aMessage & vbNewLine & (i + 1) & ") " & aCDOForm.Name & vbNewLine &_
    "  ID: " & aCDOForm.Id & vbNewLine &_ 
    "  Patient: " & aCDOForm.Patient.SurnameFirstName & vbNewLine &_
    "  HRC Type: " & aCDOForm.HRC.TypeId & vbNewLine &_        
    "  DesignDataID: " & aCDOForm.DesignDataID & vbNewLine 
    
  if not aCDOForm.BCase is nothing then
    aMessage = aMessage & "  Case: " & aCDOForm.BCase.CaseTitle & vbNewLine
  else
    aMessage = aMessage & "  Case: - " & vbNewLine    
  end if

  set aDataItems = aCDOForm.DataItems
  aMessage = aMessage & "  Data Items Count: " & aDataItems.Count & vbNewLine &_
    "  Filled Data Items: " & vbNewLine  
  for j = 0 to aDataItems.Count - 1
    set aItem = aDataItems.Item(j)
    if aItem.Value <> "" then 
      aMessage = aMessage & vbTab & aItem.Code & " = " & aItem.Value & vbNewLine
    end if     
  next 'j
next ' i
 
Profile.MsgBox(aMessage)