ISCDOTransaction.CreateInterestCopy

Description

This function creates an interest copy of the CDO transaction for the specified provider.

Syntax

object.CreateInterestCopy(aCopiedToProviderId[, aPOSID = 0[, aComment = ""]])

Part	Attribute	Type	Description
`object`	Required	ISCDOTransaction	The `object` always implements the ISCDOTransaction interface
`aCopiedToProviderId`	In, Required	int	ID of the copied provider
`aPOSID`	In, Optional Default value is 0	int	ID of the place of service
`aComment`	In, Optional Default value is ""	string	Some comment for the copied provider

Return Value

ISCDOTransactionInterestCopy

Returns the added interest copy for the specified provider.

Example

Create an interest copy for each CDO transaction and display some information about them.

Dim aPatient
Dim aProvider
Dim aCopiedToProviderId
Dim aPos
Dim aPOSID
Dim aFilter 
Dim aCDOTransactions, aCDOTransaction
Dim aCDOTransIntCopies, aCDOTransIntCopy
Dim aMessage
Dim i, j

Set aPatient = Profile.SelectPatient
set aProvider = Profile.LoadProvider("VE3")
aCopiedToProviderId = aProvider.ID

set aPos = Profile.LoadProvider ("LANGLEY")
aPOSID = aPOS.Id
  
set aFilter = Profile.CreateCDOTransFilter
aFilter.PatientId = aPatient.Id
set aCDOTransactions = Profile.LoadCDOTransactions(aFilter)

aMessage = "CDO Transactions Count = " & aCDOTransactions.Count & vbNewLine
for i = 0 to aCDOTransactions.Count - 1
  set aCDOTransaction = aCDOTransactions.Item(i)
  aMessage = aMessage & vbNewLine & (i + 1) & ") " &_
    "Transaction: " & vbNewLine & "    CreatedOn: " &_
    aCDOTransaction.CreatedOn & vbNewLine   
  
  aCDOTransaction.CreateInterestCopy aCopiedToProviderId, aPOSID, "Please, review ASAP" 
  aMessage = aMessage &_
    "    The interest copy for " & aProvider.FullName &_
    " was successfully created" & vbNewLine
  
  set aCDOTransIntCopies = aCDOTransaction.InterestCopies
  aMessage = aMessage & vbNewLine &_  
    "    Interest Copies Count = " & aCDOTransIntCopies.Count  & vbNewLine 
  for j = 0 to aCDOTransIntCopies.Count - 1
    set aCDOTransIntCopy = aCDOTransIntCopies.Item(j)
  
    aMessage = aMessage & vbNewLine &_
      "    Interest Copy Information: " & vbNewLine &_
      "      GUID: " & aCDOTransIntCopy.GUID & vbNewLine &_
      "      ID: " & aCDOTransIntCopy.ID & vbNewLine &_
      "      Created On: " & aCDOTransIntCopy.CreatedOn & vbNewLine &_
      "      Modified On: " & aCDOTransIntCopy.ModifiedOn & vbNewLine &_
      "      Copied To: " & aCDOTransIntCopy.CopiedTo.FullName  & vbNewLine &_      
      "      Comment: " & aCDOTransIntCopy.Comment & vbNewLine &_
      "      Is Signed: " & aCDOTransIntCopy.IsSigned & vbNewLine    
  next 'j  
next 'i     

Profile.MsgBox(aMessage)

Note:

In Profile Client v8 on User Interface Interest Copy can be found and added in Clinical > Medical Record > Results > Open the CDO transaction > Transaction > Copies To > Add provider.

Version information

Added in v8.4.20