ISCase.GetBudgetRequests

Example

Display the number of the cases loaded on the basis of the selected filter, their titles, some information about the related budget requests, the dates and time when these cases were opened.

sub main
  Dim aPatient 
  Dim aFilter
  Dim aCases, aCase
  Dim aBudgetRequests, aBudgetRequest 
  Dim i, j
  Dim aMessage
  
  Set aPatient = Profile.SelectPatient
  set aFilter = Profile.CreateCasesFilter
  aFilter.Patient = aPatient
  set aCases = Profile.LoadCases(aFilter)

  aMessage = "The number of the cases for " & aPatient.SurnameFirstName &_ 
    " = " & aCases.Count 
  
  for i = 0 to aCases.Count -1
    set aCase = aCases.Item(i)
    set aBudgetRequests = aCase.GetBudgetRequests
    aMessage = aMessage & vbNewLine & (i + 1) & ") " & aCase.CaseTitle &_ 
      " was opened on " & aCase.OpenedOn 
    if aBudgetRequests.Count > 0 then
      aMessage = aMessage & vbNewLine & "    Budget Requests: "
      for j = 0 to aBudgetRequests.Count -1
        set aBudgetRequest = aBudgetRequests.Item(j)
        aMessage = aMessage & vbNewLine & "    -Request Info:" & vbNewLine &_ 
          "       Date: " & aBudgetRequest.Date & vbNewLine &_ 
          "       Reference = " & aBudgetRequest.Reference & vbNewLine &_ 
          "       Status = " & GetStatusDescr(aBudgetRequest.Status) 
        if not aBudgetRequest.Phase is nothing then 
          aMessage = aMessage & vbNewLine &_ 
            "       Phase = " & aBudgetRequest.Phase.Description
        end if       
      next    
    end if   
  next      

  Profile.MsgBox(aMessage)
end sub

function GetStatusDescr(aStatus)
  Dim aResult

  Select Case aStatus
    Case 1
      aResult = "Unknown"
    Case 2
      aResult = "Pending"
    Case 4
      aResult = "Accepted"
    Case 8
      aResult = "Rejected"
    Case Else
      aResult = "Not Identified"            
  End Select
  
  GetStatusDescr = aResult
end function