ISCase.GetBudgetSummaryItems

Example

Display the number of the cases loaded on the basis of the selected filter, their titles, some information about the related budget summary items, the dates and time when these cases were opened.

Dim aPatient 
Dim aFilter
Dim aCases, aCase
Dim aPhase
Dim aBudgetSummaryItems, aBudgetSummaryItem
Dim aService
Dim i, j
Dim aMessage
  
Set aPatient = Profile.SelectPatient
set aFilter = Profile.CreateCasesFilter
aFilter.Patient = aPatient
set aCases = Profile.LoadCases(aFilter)
set aPhase = Profile.LoadShortCodeByCodeType("INITIAL", 127)  'sscBudgetPhase 
  
if aPhase is nothing then 
  Profile.MsgBox("No short code with the specified code")
  exit sub
end if
     
aMessage = "The number of the cases for " & aPatient.SurnameFirstName &_ 
  " = " & aCases.Count 
  
for i = 0 to aCases.Count -1
  set aCase = aCases.Item(i)    
  set aBudgetSummaryItems = aCase.GetBudgetSummaryItems(aPhase.ID)
  aMessage = aMessage & vbNewLine & (i + 1) & ") " & aCase.CaseTitle &_ 
    " was opened on " & aCase.OpenedOn 
  if aBudgetSummaryItems.Count > 0 then
    aMessage = aMessage & vbNewLine & "    Budget Summary Items: "
    for j = 0 to aBudgetSummaryItems.Count -1
      set aBudgetSummaryItem = aBudgetSummaryItems.Item(j)
      if aBudgetSummaryItem.ServiceID <> 0 then
        aService = Profile.LoadService(aBudgetSummaryItem.ServiceCode).Description
      else
        aService = "No selected service" 
      end if 
      aMessage = aMessage & vbNewLine & "    -Budget Summary Item Info:" & vbNewLine &_ 
        "         Service: " & aService & vbNewLine &_
        "         Invoiced: " & aBudgetSummaryItem.Invoiced & vbNewLine &_ 
        "         Pending: " & aBudgetSummaryItem.Pending & vbNewLine &_ 
        "         Residual: " & aBudgetSummaryItem.Residual & vbNewLine  
    next    
  end if   
next      

Profile.MsgBox(aMessage)