ISCase.LoadCaseTeam

Description

This function returns the case team members loaded on the basis of the selected filter.

Syntax

object.LoadCaseTeam(aFilter)

Part	Attribute	Type	Description
`object`	Required	ISCase	The `object` always implements the ISCase interface
`aFilter`	In, Required	ISCaseTeamFilter	The object that defines conditions for filtering

Return Value

ISList

Returns the case team members loaded on the basis of the selected filter.

Example

Add a new case team member for the created case and display the full name and the role of this member.

Dim aTrans
Dim aFilter
Dim aCaseTypes, aCaseType
Dim aPatient 
Dim aProvider
Dim aRole
Dim aNewCase
Dim aNewCaseTeam
Dim aCaseTeams, aCaseTeam
Dim aMessage

Set aTrans = Profile.StartMapTransaction  

set aFilter = Profile.CreateCaseTypesFilter
aFilter.Description = "Case Type 1" 
set aCaseTypes = Profile.LoadCaseTypes(aFilter)
if aCaseTypes.Count = 0 then 
  Profile.MsgBox("No case type with the specified description")
  exit sub
end if 
set aCaseType = aCaseTypes.Item(0)

set aPatient = Profile.SelectPatient
set aProvider = Profile.LoadProvider("MM")
set aRole = Profile.LoadShortCodeByCodeType("32", 87)  'sscCaseTeamRoles

if (aProvider.ID = 0) or (aRole is nothing) then
  Profile.MsgBox("The source data for a new case team is incorrect")
  exit sub
end if

set aNewCase = Profile.CreateCase(aPatient.ID)
aNewCase.CaseTitle = "New Case0032"
aNewCase.CaseType = aCaseType

set aNewCaseTeam = aNewCase.AddCaseTeam
aNewCaseTeam.RoleId = aRole.ID
aNewCaseTeam.Patient = aPatient.ID
aNewCaseTeam.ProviderType = 0  'sptProv
aNewCaseTeam.PersonId = aProvider.ID

aTrans.SnapShot 

set aFilter = Profile.CreateCaseTeamFilter
aFilter.RoleCode = aRole.Code 
set aCaseTeams = aNewCase.LoadCaseTeam(aFilter)

aMessage = aMessage & vbNewLine & aNewCase.CaseTitle &_ 
  " was opened on " & aNewCase.OpenedOn & vbNewLine & "Case Teams Count = " &_ 
  aCaseTeams.Count 
  
for each aCaseTeam in aCaseTeams    
  aMessage = aMessage & vbNewLine & "   -Team Role: " &_ 
    Profile.LoadShortCode(aCaseTeam.RoleId).Description & vbNewLine &_ 
    "   -Provider: " & Profile.LoadProviderById(aCaseTeam.PersonId).FullName
next    

Profile.MsgBox(aMessage)

Note:

In Profile Client v8 on User Interface Case Team can be found in Organisation > Work Centre > Work > Cases > Edit Case > Administrative > Care Team.

Version information