ISCaseBudgetRequest.GetJournals

Example

Display the number of the budget requests related to the selected case and some information about them, including the log of comments on these requests.

sub main
  Dim aResult 
  Dim aPatientID 
  Dim aCaseID
  Dim aCase
  Dim aBudgetRequests, aBudgetRequest 
  Dim aJournals, aJournal
  Dim i,j
  Dim aMessage
  
  aResult = Profile.Lookup_PatientCaseSearch(aPatientID, aCaseID, "Case Search", True)

  Set aCase = Profile.OpenCase(aCaseID)
  set aBudgetRequests = aCase.GetBudgetRequests
  aMessage = aCase.CaseTitle & " was opened on " & aCase.OpenedOn &_
    vbNewLine & "Budget Requests Count = " & aBudgetRequests.Count  
  
  for i = 0 to aBudgetRequests.Count -1
    set aBudgetRequest = aBudgetRequests.Item(i)
    set aJournals = aBudgetRequest.GetJournals
    aMessage = aMessage & vbNewLine & (i + 1) & ") Request Info:" & vbNewLine &_ 
      "       Date: " & aBudgetRequest.Date & vbNewLine &_ 
      "       Reference = " & aBudgetRequest.Reference & vbNewLine &_ 
      "       Status = " & GetStatusDescr(aBudgetRequest.Status) 
    for j = 0 to aJournals.Count -1
      set aJournal = aJournals.Item(j) 
      aMessage = aMessage & vbNewLine & "     Journal Info: " & vbNewLine &_ 
        "       Date: " & aJournal.Date & vbNewLine &_ 
        "       Comments = " & aJournal.Comments & vbNewLine &_ 
        "       User = " & aJournal.User.FullName
    next            
  next          

  Profile.MsgBox(aMessage)
end sub

function GetStatusDescr(aStatus)
  Dim aResult

  Select Case aStatus
    Case 1
      aResult = "Unknown"
    Case 2
      aResult = "Pending"
    Case 4
      aResult = "Accepted"
    Case 8
      aResult = "Rejected"
    Case Else
      aResult = "Not Identified"            
  End Select
  
  GetStatusDescr = aResult
end function