ISCaseEquipLoanFilter.ItemID

Description

This filter property is used to load the case equipment loans by ID of the service that is used as the loan item.

Syntax

object.ItemID

Part	Attribute	Type	Description
`object`	Required	ISCaseEquipLoanFilter	The `object` always implements the ISCaseEquipLoanFilter interface

Return Value

int

Example

Display the number of the case equipment loans loaded on the basis of the selected filter and some information about them.

Dim aPatient
Dim aFilter
Dim aCaseEquipLoans, aCaseEquipLoan
Dim aMessage
Dim i  
    
Set aPatient = Profile.SelectPatient
set aFilter = Profile.CreateCaseEquipLoanFilter
aFilter.Patient = aPatient
aFilter.OnlyReturned = False
aFilter.OnlyNotReturned = False
aFilter.ItemID = Profile.LoadService("1").ID
set aCaseEquipLoans = Profile.LoadCaseEquipLoans(aFilter)

aMessage = "Case Equipment Loans Count = " & aCaseEquipLoans.Count & vbNewLine

for i = 0 to aCaseEquipLoans.Count - 1
  set aCaseEquipLoan = aCaseEquipLoans.Item(i)
  set aPatient = Profile.LoadPatient(aCaseEquipLoan.PatientId) 
  aMessage = aMessage & vbNewLine & (i + 1) & ". " &_
    "Started On: " & aCaseEquipLoan.StartedOn & vbNewLine &_
    "Expected On: " & aCaseEquipLoan.ExpectedOn & vbNewLine &_
    "Patient: " & aPatient.SurnameFirstName & vbNewLine &_
    "Comment: " & aCaseEquipLoan.Comment & vbNewLine &_
    "ID: " & aCaseEquipLoan.ID & vbNewLine &_
    "Loan Item: " & Profile.LoadServiceByID(aCaseEquipLoan.ItemID).Description & vbNewLine &_
    "Is Returned: " & aCaseEquipLoan.IsReturned & vbNewLine
  if aCaseEquipLoan.CaseID > 0 then
    aMessage = aMessage & "Case: " & Profile.OpenCase(aCaseEquipLoan.CaseID).CaseTitle & vbNewLine
  else
    aMessage = aMessage & "Case: -" & vbNewLine  
  end if    
next

Profile.MsgBox(aMessage)

Note:

In Profile Client v8 on User Interface Item ID cannot be found, but Item can be found in Clinical > Medical Record > Equipment > Loan Item or in Clinical > Medical Record > Cases > Open the selected case > Equipment > Loan Item.

Version information

Added in v7.8.0