ISEncounter.RecalculateDefaultPrivacy

Example

Display the privacy role for the encounters before and after the changes.

sub main
  Dim aPatient        
  Dim aFilter  
  Dim aEncounters, aEncounter
  Dim i                                                                                                            
  Dim aMessage

  set aPatient = Profile.SelectPatient 
  set aFilter = Profile.CreateEncounterFilter
  aFilter.PatientId = aPatient.ID 
  set aEncounters = aPatient.LoadEncounters(aFilter)

  aMessage = "Encounters Count = " & aEncounters.Count

  for i = 0 to aEncounters.Count - 1
    set aEncounter = aEncounters.Item(i)
    aMessage = aMessage & vbNewLine & (i + 1) & ". BEFORE: " & vbNewLine &_
      GetEncounterInfo(aEncounter)

    aEncounter.RecalculateDefaultPrivacy
 
    aMessage = aMessage & vbNewLine & "  AFTER: " & vbNewLine &_
      GetEncounterInfo(aEncounter) & vbNewLine  
  next   
                                              
  Profile.MsgBox(aMessage)
end sub


function GetEncounterInfo(aEncounter)
  Dim aInfo

  aInfo = _
    "Date: " & aEncounter.Date & vbNewLine &_                            
    "Date Created: " & aEncounter.DateCreated & vbNewLine &_
    "Date Altered: " & aEncounter.DateAltered & vbNewLine &_
    "Provider Code: " & aEncounter.ProviderCode & vbNewLine
  if not aEncounter.Role is nothing then
    aInfo = aInfo & "Role Name: " & aEncounter.Role.RoleName & vbNewLine   
  else
    aInfo = aInfo & "Role Name: -"     
  end if  
 
  GetEncounterInfo = aInfo
end function