ISFamilyProblemFilter.MaxCount

Description

This filter property is used to load the maximum number of family problems included in the batch.

Syntax

object.MaxCount

Part	Attribute	Type	Description
`object`	Required	ISFamilyProblemFilter	The `object` always implements the ISFamilyProblemFilter interface

Return Value

int

Example

Display the number of the family problems loaded on the basis of the selected filter and some information about them.

Dim aPatient
Dim aFilter
Dim aFamilyProblems, aFamilyProblem
Dim aLastId
Dim aTotalCount 
Dim aMessage
Dim i

Set aPatient = Profile.SelectPatient
set aFilter = Profile.CreateFamilyProblemFilter
aFilter.PatientID = aPatient.ID
aFilter.StartFromId = 0
aFilter.MaxCount = 3 'the size of the batch

aLastId = 0
aTotalCount = 0
do
  set aFamilyProblems = aFilter.Load

  for i = 0 to aFamilyProblems.Count - 1 
    set aFamilyProblem = aFamilyProblems.Item(i)
    aMessage = aMessage & vbNewLine & (i + 1) & ") " &_
      "Dx Description: " & aFamilyProblem.DxDescription & vbNewLine &_
      "Date: " & aFamilyProblem.Date & vbNewLine &_
      "ID: " & aFamilyProblem.ID & vbNewLine &_ 
      "DT Modified: " & aFamilyProblem.GetDTModified & vbNewLine
      
    aTotalCount = aTotalCount + 1 
    
    if aFamilyProblem.Id > aLastId then aLastId = aFamilyProblem.Id   
  next 
     
  aFilter.StartFromId = aLastId + 1
  aMessage = aMessage & vbNewLine
loop until aFamilyProblems.Count = 0

aMessage = "Family Problems Count: " & aTotalCount & vbNewLine & aMessage

Profile.MsgBox(aMessage)

Note:

In Profile Client v8 on User Interface Family Problems can be found in Clinical > Clinical Details > Family/Social History.

Version information

Added in v8.5.0