ISFlowChartDef.DisplayTimeMode

Example

Display the number of the flow sheets loaded on the basis of the selected filter and some information about them.

Dim aPatient
Dim aPatientID
Dim aFilter
Dim aFlowChartDefs, aFlowChartDef
Dim aMessage
Dim i, j
Dim aMeasures, aMeasure
Dim aLastDate, aLastValue 

Set aPatient = Profile.SelectPatient
aPatientID = aPatient.ID 
set aFilter = Profile.CreateFlowChartFilter
aFilter.DateFrom = #03/04/2004#
aFilter.DateTo = #03/04/2008#
aFilter.Last = 2

set aFlowChartDefs = Profile.GetFlowChartDefsByFilter(aPatientID, aFilter)

aMessage = "Flow Chart Defs Count = " & aFlowChartDefs.Count & vbNewLine 

for i = 0 to aFlowChartDefs.Count - 1
  set aFlowChartDef = aFlowChartDefs.Item(i)  
  aMessage = aMessage & vbNewLine & (i + 1) & ". " &_
    "Caption: " & aFlowChartDef.Caption & vbNewLine &_
    "Display Time Mode: " & aFlowChartDef.DisplayTimeMode & vbNewLine 

  set aMeasures = aFlowChartDef.Measures 
  if not aMeasures is nothing then
    aMessage = aMessage & "    Measures Count = " &_
      aMeasures.Count & vbNewLine
    for j = 0 to aMeasures.Count - 1
      set aMeasure = aMeasures.Item(j) 'ISFlowChartDefItem
      aMeasure.CalcLastValue aPatientID, aLastDate, aLastValue 
      
      aMessage = aMessage & (i + 1) & "." & (j + 1) & ". Measure information: " & vbNewLine &_
        "    Caption: " & aMeasure.Caption & vbNewLine &_      
        "    Units: " & aMeasure.Units & vbNewLine &_  
        "    Last Date: " & aLastDate & vbNewLine &_
        "    Last Value: " & aLastValue & vbNewLine            
    next 'j
  end if 

next 'i    

Profile.MsgBox(aMessage)