ISHRObservation.SetConcept

Example

Replace the specified concepts linked to the observations.

sub main
  Dim aPatient
  Dim aFilter
  Dim aHRObservations, aHRObservation
  Dim aConcepts, aNewConcept  
  Dim aMessage
  Dim i   

  Set aPatient = Profile.SelectPatient
  set aFilter = Profile.CreateObservationFilter
  aFilter.PatientId = aPatient.ID 
  aFilter.DateFrom = #01/01/2019#
  aFilter.DateTo = #01/01/2020#
  set aHRObservations = aFilter.Load

  aMessage = "HR Observations Count: " & aHRObservations.Count & vbNewLine

  set aFilter = Profile.CreateConceptsFilter
  aFilter.AddConceptRef "IH", "IH006", False
  set aConcepts = Profile.LoadConcepts(aFilter)
  set aNewConcept = aConcepts.Item(0)  

  for i = 0 to aHRObservations.Count - 1
    set aHRObservation = aHRObservations.Item(i)
    ProcessHRObservation aHRObservation, aNewConcept 
    aMessage = aMessage & vbNewLine & (i + 1) & ") " &_
      "Name: " & aHRObservation.Name & vbNewLine &_
      "   Code: " & aHRObservation.Code & vbNewLine &_
      "   Concept Code: " & aHRObservation.ConceptCode & vbNewLine &_
      "   Is Deleted: " & aHRObservation.IsDeleted & vbNewLine &_
      "   Termset Code: " & aHRObservation.TermsetCode & vbNewLine &_
      "   GUID: " & aHRObservation.GUID & vbNewLine &_
      "   ID: " & aHRObservation.ID & vbNewLine
  next
  Profile.MsgBox(aMessage)
end sub

sub ProcessHRObservation(aHRObservation, aNewConcept)
  if (aHRObservation.TermsetCode = "IH" and aHRObservation.ConceptCode = "z..UB") then
    aHRObservation.SetConcept aNewConcept
  end if
end sub