ISHriDataRange.DimensionMax

Example

Display the number of the HRI templates within the collection and some information about them, including the physical units of the HRI content values.

sub main
  Dim aHRITemplates, aHRITemplate 
  Dim aHRIData
  Dim i
  Dim aMessage
       
  Set aHRITemplates = Profile.GetHRITemplates

  aMessage = "There are " & aHRITemplates.Count & " HRI Templates: "

  for i = 0 to aHRITemplates.Count - 1 
    set aHRITemplate = aHRITemplates.Item(i)
    set aHRIData = aHRITemplate.HRI
 
    aMessage = aMessage & vbNewLine & (i + 1) & ") " &_
      "Concept: " & aHRIData.Concept.Name & vbNewLine &_   
      "Typing type: " & aHRIData.TypingType & vbNewLine 
    select case aHRIData.TypingType
      case 1 'tshtQuantity 
        aMessage = aMessage &_
          "Dimension: " & GetPhysUnitAsStr(aHRIData.Dimension) & vbNewLine          
      case 2 'tshtRange  
        aMessage = aMessage &_
          "Dimension Min: " & GetPhysUnitAsStr(aHRIData.DimensionMin) & vbNewLine &_
          "Dimension Max: " & GetPhysUnitAsStr(aHRIData.DimensionMax) & vbNewLine            
      case 3 'tshtRatio   
        aMessage = aMessage &_
          "Dimension Numerator: " & GetPhysUnitAsStr(aHRIData.DimensionNumerator) & vbNewLine &_
          "Dimension Denominator: " & GetPhysUnitAsStr(aHRIData.DimensionDenominator) & vbNewLine   
    end select
  next 'i

  Profile.MsgBox(aMessage)
end sub

function GetPhysUnitAsStr(aPhysUnit)
  Dim aInfo
  
  if aPhysUnit is nothing then
    aInfo = "none"
  else
    aInfo = aPhysUnit.Name
  end if      
  GetPhysUnitAsStr = aInfo
end function