ISInvoice.MedicareType

Example

Display the number of the invoices loaded on the basis of the selected filter and some information about them, including their types.

sub main
  Dim aPatient
  Dim aFilter
  Dim aInvoices, aInvoice
  Dim aMessage
  Dim i    

  Set aPatient = Profile.SelectPatient
  set aFilter = Profile.CreateInvoiceFilter
  aFilter.PatientId = aPatient.ID
  set aInvoices = aFilter.Load

  aMessage = "Invoices Count = " & aInvoices.Count & vbNewLine

  for i = 0 to aInvoices.Count - 1
    set aInvoice = aInvoices.Items(i)
    aMessage = aMessage & vbNewLine & (i + 1) & ". " &_
      "Date: " & aInvoice.Date & vbNewLine &_
      "    ID: " & aInvoice.ID & vbNewLine &_
      "    GUID: " & aInvoice.GUID & vbNewLine &_
      "    Pos Code: " & aInvoice.PosCode & vbNewLine &_  
      "    Reference: " & aInvoice.Reference & vbNewLine &_  
      "    Medicare Type: " & GetMedicareTypeDescr(aInvoice.MedicareType) & vbNewLine     
  next
  
  Profile.MsgBox(aMessage)
end sub    

function GetMedicareTypeDescr(aType)
  Dim aResult

  Select Case aType
    Case 0
      aResult = "Unknown"
    Case 1
      aResult = "General"
    Case 2
      aResult = "Specialist"
    Case 3
      aResult = "Pathologist"         
  End Select
  
  GetMedicareTypeDescr = aResult
end function