ISInvoiceLine.ChargeRate

Example

Display the number of the invoices loaded on the basis of the selected filter and some information about the invoice lines, including the rates applied to the services.

Dim aPatient
Dim aFilter
Dim aInvoices, aInvoice
Dim aInvoiceLines, aInvoiceLine
Dim aMessage
Dim i, j    

Set aPatient = Profile.SelectPatient
set aFilter = Profile.CreateInvoiceFilter
aFilter.PatientId = aPatient.ID
set aInvoices = aFilter.Load

aMessage = "Invoices Count = " & aInvoices.Count & vbNewLine

for i = 0 to aInvoices.Count - 1
  set aInvoice = aInvoices.Items(i)
  set aInvoiceLines = aInvoice.InvoiceLines 
  aMessage = aMessage & vbNewLine & (i + 1) & ". " &_
    "Date: " & aInvoice.Date & vbNewLine &_
    "    ID: " & aInvoice.ID & vbNewLine &_
    "    Invoice Lines Count: " & aInvoiceLines.Count & vbNewLine 
  for j = 0 to aInvoiceLines.Count - 1
    set aInvoiceLine = aInvoiceLines.Item(j)
    aMessage = aMessage & (i + 1) & "." & (j + 1) &_
      " -Description: " & aInvoiceLine.Description & vbNewLine &_
      "      -Date Time From: " & aInvoiceLine.DateTimeFrom & vbNewLine &_
      "      -Date Time To: " & aInvoiceLine.DateTimeTo & vbNewLine 
    if not aInvoiceLine.ChargeRate is nothing then 
       aMessage = aMessage & "      -Charge Rate: " &_
         aInvoiceLine.ChargeRate.Description & vbNewLine
    end if
  next 'j    
next 'i    

Profile.MsgBox(aMessage)