ISMedOrderItemsFilter.AuthorIds

Description

This filter property is used to load the medication order items by IDs of the providers who ordered them.

Syntax

object.AuthorIds

Part	Attribute	Type	Description
`object`	Required	ISMedOrderItemsFilter	The `object` always implements the ISMedOrderItemsFilter interface

Return Value

ISIntCollection

Example

Display the number of the medication order items loaded on the basis of the selected filter and some information about them.

Dim aProvidersFilter                                 
Dim aProviders, aProvider
Dim aIntCollection 
Dim aPatient
Dim aOrderItemsFilter
Dim aMedOrderItems, aMedOrderItem
Dim aMedication 
Dim aMessage
Dim i  

Set aProvidersFilter = Profile.CreateProvidersFilter
aProvidersFilter.Category = 2 'pcProvider
set aProviders = Profile.LoadProvidersByFilter(aProvidersFilter)

set aIntCollection = Profile.CreateIntCollection

for each aProvider in aProviders
  aIntCollection.Add(aProvider.ID)
next

set aPatient = Profile.SelectPatient
set aOrderItemsFilter = Profile.MakeMedOrderItemsFilter
aOrderItemsFilter.PatientId = aPatient.ID
aOrderItemsFilter.AuthorIds = aIntCollection 

set aMedOrderItems = Profile.LoadMedOrderItems(aOrderItemsFilter)

aMessage = "Medication Order Items Count = " & aMedOrderItems.Count & vbNewLine

for i = 0 to aMedOrderItems.Count - 1
  set aMedOrderItem = aMedOrderItems.Item(i)
  set aMedication = aMedOrderItem.Medication
  set aProvider = Profile.LoadProviderById(aMedication.OrderedByID) 
   
  aMessage = aMessage & vbNewLine & (i + 1) & ") " &_
    "Medication Name: " & aMedication.RxName & vbNewLine &_
    "Date: " & aMedication.Date & vbNewLine &_
    "Author: " & aProvider.FullName   
next 

Profile.MsgBox(aMessage)

Note:

In Profile Client v8 on User Interface Author Ids cannot be found, but Author can be found in Clinical > Medical Record > MedChart > Author.

Version information

Added in v7.10.90