ISPatientProblem.Emphasis

Example

Display the codes, descriptions and significance levels of the patient's problems in each category.

sub main()
  Dim aPatient
  Dim aProblemList
  Dim aCategories
  Dim aCategory
  Dim aProblems
  Dim aProblem
  Dim aMessage

  Set aPatient = Profile.SelectPatient

  set aProblemList = aPatient.ProblemList
  set aCategories = aProblemList.Categories

  for each aCategory in aCategories
    aMessage = aMessage & vbNewLine & "---------" & aCategory.Description &_ 
      "---------"  & vbNewLine & vbNewLine 
    set aProblems = aCategory.Problems
    for each aProblem in aProblems
      if aProblem.ProblemType = 6 then  'ptPregnancy  
        aMessage = aMessage & "    " & "Code: " & aProblem.DxCode &_ 
          "; Description: " & aProblem.DxDescription & vbNewLine
      else 
        aMessage = aMessage & "    " &_ 
          "Code: " & aProblem.DxCode & "; Description: " & aProblem.DxDescription &_ 
          " (Emphasis = " & GetEmphasisDescr(aProblem.Emphasis) & ")" & vbNewLine
      end if  
    next
  next 

  Profile.MsgBox(aMessage)
end sub 

function GetEmphasisDescr(ByVal aEmphasis)
  Dim aResult

  Select Case aEmphasis
    Case 0
      aResult = "Low"
    Case 1
      aResult = "Medium"
    Case 2
      aResult = "High"       
  End Select
  
  GetEmphasisDescr = aResult
end function