ISPatientProblemVers.NatureID

Example

Display the codes, descriptions and nature descriptions for the patient's problems of 'Adverse' and 'Diagnosis' types in each problem version.

sub main
  Dim aPatient
  Dim aProblemList
  Dim aCategories
  Dim aMessage

  Set aPatient = Profile.SelectPatient

  set aProblemList = aPatient.ProblemList
  set aCategories = aProblemList.Categories

  aMessage = ShowCategoryProblems(aCategories.Item(0)) &_
    ShowCategoryProblems(aCategories.Item(1)) 

  Profile.MsgBox(aMessage)    

end sub

function ShowCategoryProblems(aCategory)
  Dim aMessage
  Dim aProblems, aProblem
  Dim aFilter
  Dim aProblemVersColl, aVersion
  
  aMessage = vbNewLine & vbNewLine &_
    "---------" & aCategory.Description & "---------"  & vbNewLine
  
  set aProblems = aCategory.Problems   
  for each aProblem in aProblems 
    aMessage = aMessage & "    " & GetProblemInfo(aProblem) & vbNewLine
    set aFilter = Profile.CreateVersionFilter
    aFilter.FromDate = #01/01/2019#
    aFilter.ToDate = #06/06/2019#
    set aProblemVersColl = aProblem.FindVersions(aFilter)
    for each aVersion in aProblemVersColl
      aMessage = aMessage & "      -" & GetProblemInfo(aVersion) & vbNewLine 
    next ' aVersion                  
  next ' aProblem 

  ShowCategoryProblems = aMessage
end function

function GetProblemInfo(aProblem)
  Dim aInfo
  Dim aNatureShortCode, aNatureDescription

  aInfo = "Code: " & aProblem.DxCode & "; Description: " & aProblem.DxDescription
  
  set aNatureShortCode = Profile.LoadShortCode(aProblem.NatureID)
  
  if aNatureShortCode is nothing then 
    aNatureDescription = " --- "
  else    
    aNatureDescription = aNatureShortCode.Description
  end if      
    
  aInfo = aInfo & " (Nature Description = " & aNatureDescription & ")"
  
  GetProblemInfo = aInfo
end function