ISPatientProblemVers.ProviderCode

Example

Display the codes, descriptions of the patient's problems and the providers, these problems are assigned to in each version.

sub main
  Dim aPatient
  Dim aProblemList
  Dim aCategories, aCategory
  Dim aProblems, aProblem
  Dim aFilter
  Dim aProblemVersColl, aVersion
  Dim aMessage
  
  Set aPatient = Profile.SelectPatient

  set aProblemList = aPatient.ProblemList
  set aCategories = aProblemList.Categories

  for each aCategory in aCategories
    aMessage = aMessage & vbNewLine & "---------" & aCategory.Description &_ 
      "---------"  & vbNewLine & vbNewLine 
    set aProblems = aCategory.Problems
    for each aProblem in aProblems 
      aMessage = aMessage & vbNewLine & "    " & GetProblemInfo(aProblem) 
      set aFilter = Profile.CreateVersionFilter
      aFilter.FromDate = #01/01/2019#
      aFilter.ToDate = #09/06/2019#
      set aProblemVersColl = aProblem.FindVersions(aFilter)
      for each aVersion in aProblemVersColl
        aMessage = aMessage & vbNewLine & "      -" & GetProblemInfo(aVersion) 
      next ' aVersion                  
    next ' aProblem
  next ' aCategory 

  Profile.MsgBox(aMessage)
end sub


function GetProblemInfo(aProblem)
  Dim aInfo

  aInfo = "Code: " & aProblem.DxCode & "; Description: " & aProblem.DxDescription
  if not aProblem.ProviderCode = "" then  
    aInfo = aInfo & "; Provider is " &_ 
      Profile.LoadProvider(aProblem.ProviderCode).FullName    
  end if
  GetProblemInfo = aInfo
end function