ISPatientRecallVisitVers.ExtProvider

Example

Display the full name of the external provider in the selected intervention version.

sub main
  Dim aPatient
  Dim aRecallPlans
  Dim aOnDate
  Dim aPlan
  Dim aVisit
  Dim aVisits
  Dim aVisitVers
  Dim aExtProvider
  Dim aExtProviderVers
  Dim aMessage
  Dim aExtProvName 
  Dim aExtProvVersName

  Set aPatient = Profile.SelectPatient
  set aRecallPlans = aPatient.RecallPlans
   
  if aRecallPlans.Count = 0 then
    Profile.MsgBox("The patient has no care plans!")
    exit sub
  end if   

  aOnDate = #03/18/2019 11:41:59#
 
  for each aPlan in aRecallPlans
    aMessage = aMessage & vbNewLine & "PLAN: '" & aPlan.Description & "'"
    set aVisits = aPlan.Visits  
      
    if aVisits.Count = 0 then
      aMessage = aMessage & vbNewLine & "There are no interventions in the plan!"
    end if  
    for each aVisit in aVisits
      aMessage = aMessage & vbNewLine & "INTERVENTION: '" & aVisit.Description & "'"    
      set aVisitVers = aVisit.VersionOnDate(aOnDate)
      
      if aVisitVers is nothing then    
        aMessage = aMessage & vbNewLine &_ 
          "  There is no version of the intervention on this date!"
      else
      
        set aExtProvider = aVisit.ExtProvider
        if aExtProvider is nothing then
          aExtProvName = "Unassigned"
        else
          aExtProvName = aExtProvider.FullName
        end if     

        set aExtProviderVers = aVisitVers.ExtProvider        
        if aExtProviderVers is nothing then
          aExtProvVersName = "Unassigned"
        else
          aExtProvVersName = aExtProviderVers.FullName
        end if

        aMessage = aMessage & vbNewLine & " -- Current intervention: " &_
          " External provider: " & aExtProvName & "  /  -- " &_
          " Intervention version on the specified date: External provider: " &_
          aExtProvVersName 
      end if    
    next
  next   

  Profile.MsgBox(aMessage)
  
end sub