ISPatientRecallVisitVers.RecallObjective

Example

Display the name of the care plan objective the selected intervention version is linked to.

sub main
  Dim aPatient
  Dim aRecallPlans
  Dim aOnDate
  Dim aPlan
  Dim aVisit
  Dim aVisits
  Dim aVisitVers
  Dim aRecallObj
  Dim aRecallObjVers
  Dim aRecallObjName
  Dim aRecallObjVersName
  Dim aMessage
  
  Set aPatient = Profile.SelectPatient
  set aRecallPlans = aPatient.RecallPlans
   
  if aRecallPlans.Count = 0 then
    Profile.MsgBox("The patient has no care plans!")
    exit sub
  end if   

  aOnDate = #03/18/2019 11:41:59#
 
  for each aPlan in aRecallPlans
    aMessage = aMessage & vbNewLine & "PLAN: '" & aPlan.Description & "'"
    set aVisits = aPlan.Visits  
      
    if aVisits.Count = 0 then
      aMessage = aMessage & vbNewLine & "There are no interventions in the plan!"
    end if  
    for each aVisit in aVisits
      aMessage = aMessage & vbNewLine & "INTERVENTION: '" & aVisit.Description & "'"    
      set aVisitVers = aVisit.VersionOnDate(aOnDate)
      
      if aVisitVers is nothing then    
        aMessage = aMessage & vbNewLine &_ 
          "  There is no version of the intervention on this date!"
      else      
        if aVisit.RecallObjectiveId > 0 then
          set aRecallObj = Profile.LoadRecallObjectiveByID(aVisit.RecallObjectiveId)
          aRecallObjName = aRecallObj.DisplayName
        else
          aRecallObjName = "Unassigned" 
        end if 
      
        set aRecallObjVers = aVisitVers.RecallObjective        
        if aRecallObjVers is nothing then
          aRecallObjVersName = "Unassigned"
        else
          aRecallObjVersName = aRecallObjVers.DisplayName
        end if

        aMessage = aMessage & vbNewLine & " -- Current intervention: " &_
          " RecallObjective: " & aRecallObjName & "  /  -- " &_
          " Intervention version on the specified date: RecallObjective: " &_
          aRecallObjVersName 
      end if    
    next
  next   

  Profile.MsgBox(aMessage)
  
end sub