ISPatientRecallVisitVers.SnapshotDate

Example

Display the date and time the snapshot of the intervention version was shown.

sub main
  Dim aPatient
  Dim aRecallPlans
  Dim aOnDate
  Dim aPlan
  Dim aVisit
  Dim aVisits
  Dim aVisitVers
  Dim aMessage

  Set aPatient = Profile.SelectPatient
  set aRecallPlans = aPatient.RecallPlans
   
  if aRecallPlans.Count = 0 then
    Profile.MsgBox("The patient has no care plans!")
    exit sub
  end if   

  aOnDate = #03/18/2019 10:18:59#
 
  for each aPlan in aRecallPlans
    aMessage = aMessage & vbNewLine & "PLAN: '" & aPlan.Description & "'"
    set aVisits = aPlan.Visits  
      
    if aVisits.Count = 0 then
      aMessage = aMessage & vbNewLine & "There are no interventions in the plan!"
    end if
      
    for each aVisit in aVisits
      aMessage = aMessage & vbNewLine & "INTERVENTION: '" & aVisit.Description & "'"    
      set aVisitVers = aVisit.VersionOnDate(aOnDate)
      
      if aVisitVers is nothing then    
        aMessage = aMessage & vbNewLine &_ 
          "  There is no version of the intervention on this date!"
      else
        aMessage = aMessage & vbNewLine & "The current intervention '" &_
          aVisit.Description & "'; " & "- ID = " & aVisit.ID & " / " &_
          " The intervention on the specified date: '" & aVisitVers.Description &_
          "'; " & "- ID = " & aVisitVers.ID & " - Snapshot Date and Time = " &_
          aVisitVers.SnapshotDate 
      end if    
    next
  next   

  Profile.MsgBox(aMessage)  
end sub