ISPatientViewAudit.ValidateHash

Example

Display the number of the patient audit records loaded on the basis of the selected filter, the number of Views Audit Items in each audit record, their descriptions and validation.

sub main
  Dim aPatient
  Dim aFilter
  Dim aAuditColl
  Dim aAudit
  Dim aViewsAuditColl 
  Dim aViewAudit
  Dim aMessage 

  Set aPatient = Profile.SelectPatient
  set aFilter = Profile.CreatePatientAuditFilter
  aFilter.PatientId = aPatient.Id
  aFilter.MaxCount = 10
  aFilter.StartDate = #03/20/2019#
  aFilter.EndDate = #03/22/2019#

  set aAuditColl = Profile.GetPatientAuditCollection(aFilter)

  aMessage = "Audit Collection Items count = " & aAuditColl.Count & vbNewLine 

  'ISPatientOrCaseAudit, ISPatientViewAudit, TSPatientInfoCenterView
  for i = 0 to aAuditColl.Count - 1 
    set aAudit  = aAuditColl.Item(i)
    set aViewsAuditColl = aAudit.LoadViewsAudit  
  
    aMessage = aMessage & vbNewLine &_
      "----------------- " & aViewsAuditColl.Count &_ 
      " Audit View Items -----------------" & vbNewLine &_
      "(" & aAudit.Started & " - " & aAudit.Finished & ")"  

    for j = 0 to aViewsAuditColl.Count - 1
      set aViewAudit = aViewsAuditColl.Item(j)
      aMessage = aMessage & vbNewLine &_ 
        "   - " & aViewAudit.Description & "; The hash is " &_ 
        GetValidationDescr(aViewAudit.ValidateHash) 
    next                                                                                        
  next

  Profile.MsgBox(aMessage)
end sub

function GetValidationDescr(aDescr)
  Dim aResult

  Select Case aDescr
    Case 0
      aResult = "Undetermined"
    Case 1
      aResult = "Invalid"
    Case 2
      aResult = "Valid"          
  End Select
  
  GetValidationDescr = aResult
end function