ISProblemInstruction.LastModifiedBy

Example

Display some information about the patient problems, including the instructions to them.

Dim aPatient
Dim aProblemList                   
Dim aCategories, aCategory
Dim aProblems, aProblem
Dim aIntstructionMeasures, aInstrMeasure
Dim aInstructions, aInstruction
Dim aProvider
Dim aProblemInternal
Dim i, j
Dim aMessage

set aPatient = Profile.SelectPatient

set aProblemList = aPatient.ProblemList
set aCategories = aProblemList.Categories

for each aCategory in aCategories
  aMessage = aMessage & vbNewLine & "---------" & aCategory.Description &_ 
    "---------"  & vbNewLine
  set aProblems = aCategory.Problems
  for each aProblem in aProblems 
    aMessage = aMessage & vbNewLine &_
      "Code: " & aProblem.DxCode & "; Description: " &_ 
      aProblem.DxDescription & "; Id: " & aProblem.Id & vbNewLine
    set aIntstructionMeasures = aProblem.GetIntstructionMeasures 
    if aIntstructionMeasures is nothing then  
      aMessage = aMessage & "    " & "Code: " & aProblem.DxCode &_ 
        "; Description: " & aProblem.DxDescription & vbNewLine
    else
      for i = 0 to aIntstructionMeasures.Count - 1 
        set aInstrMeasure = aIntstructionMeasures.Item(i)
        aMessage = aMessage & "     - Measure: " & aInstrMeasure.Measure.Name & vbNewLine 
        set aInstructions = aInstrMeasure.Instructions
        for j = 0 to aInstructions.Count - 1
          set aInstruction = aInstructions.Item(j)
          aMessage = aMessage & _
            "        -- Value = " & Profile.RTF2Plain(aInstruction.MeasureValue) & vbNewLine &_
            "        -- Instruction : " & Profile.RTF2Plain(aInstruction.Instruction) & vbNewLine &_            
            "          --- Last Modified: " & aInstruction.LastModified & vbNewLine 
          set aProvider = aInstruction.LastModifiedBy
          if not aProvider is nothing then
            aMessage = aMessage & "          --- Last Modified By: " &_
              aProvider.FullName & vbNewLine 
          else
            aMessage = aMessage &_
              "          --- Last Modified By: Not defined" & vbNewLine
          end if
          set aProblemInternal = aInstruction.Problem
          if not aProblemInternal is nothing then
            aMessage = aMessage &_
              "          --- Problem ID: " &  aProblemInternal.Id  & vbNewLine
          else
            aMessage = aMessage &_
              "          --- Problem ID: 0" & vbNewLine
          end if
        next 'j
      next 'i 
    end if  
  next 'aProblem
next 'aCategory

Profile.MsgBox(aMessage)