ISProvider.RevokeRole

Example

Revoke the simple role assigned to the provider.

sub main

  Dim aFilter 
  Dim aProviders, aProvider
  Dim aTrans
  Dim aMessage

  const aRoleName = "Doctor"
  const aIncludeDeleted = false

  Set aFilter = Profile.CreateProvidersFilter
  aFilter.Category = 2 'pcProvider
  aFilter.Code = "PROV"

  set aTrans = Profile.StartMapTransaction  
  set aProviders = Profile.LoadProvidersByFilter(aFilter)

  aMessage = "BEFORE:" & GetProvidersRoleInfo(aProviders)

  for each aProvider in aProviders
    aProvider.RevokeRole aRoleName
  next 'aProvider
    
  aTrans.Commit
  
  set aTrans = Profile.StartMapTransaction  
  set aProviders = Profile.LoadProvidersByFilter(aFilter)
  
  aMessage = aMessage & vbNewLine & vbNewLine &_
    "AFTER:" & GetProvidersRoleInfo(aProviders)

  Profile.MsgBox (aMessage)
end sub


function GetProvidersRoleInfo(aProviders)
  Dim aProvider
  Dim aMessage
  Dim aRoles, aRole    

  for each aProvider in aProviders
    aMessage = aMessage & vbNewLine & vbNewLine & aProvider.FullName

    set aRoles = aProvider.GetRoles
    if aRoles.Count = 0 then
      aMessage = aMessage & " has no roles"  
    end if
  
    for i = 0 to aRoles.Count - 1 
      set aRole = aRoles.Item(i)
      aMessage = aMessage & vbNewLine & "      " & aRole.RoleName   
    next 'i    
  next 'aProvider  

  GetProvidersRoleInfo = aMessage
end function