ISProviderVers.LoadAlias

Example

sub main()

  Dim aFilter 
  Dim aProviders
  Dim aDate
  Dim aMessage

  Set aFilter = Profile.CreateProvidersFilter
  aFilter.Category = 2 'pcProvider
  aFilter.Code = "VE3"
  
  aAliasCode = "My source 1ZZZZZZ"

  set aProviders = Profile.LoadProvidersByFilter(aFilter)

  aDate = #06/10/2019#
  aMessage = GetProviderCollectionInfo(aProviders, aDate, aAliasCode)

  Profile.MsgBox(aMessage)
end sub


function GetProviderCollectionInfo(aProviders, aDate, aAliasCode)
  Dim aProvider
  Dim aProviderOnDate
  Dim aInfo
   
  aInfo = ""

  for each aProvider in aProviders
    aInfo = aInfo & vbNewLine & vbNewLine & "PROVIDER: " &_
      aProvider.FullName & vbNewLine

    set aProviderOnDate = aProvider.VersionOnDate(aDate)
    if aProviderOnDate is nothing then    
      aInfo = aInfo & vbNewLine & " - " & aProvider.FullName &_
        " (" & aProvider.Id & ") " & "  -  No Version on this date"
    else            
      aInfo = aInfo & vbNewLine & "CURRENT VERSION: " & vbNewLine &_
        "Full Name: " & aProvider.FullName & vbNewLine &_ 
        "ID: " & aProvider.Id & vbNewLine &_
        "Cell Phone: " & aProvider.CellPhone & vbNewLine &_
        "Alias: " & GetProviderAliasCodeAsText(aProvider, aAliasCode) & vbNewLine &_        
        vbNewLine & "VERSION ON DATE:  " & vbNewLine &_
        "Full Name: " & aProviderOnDate.FullName & vbNewLine &_
        "ID: " & aProviderOnDate.Id & vbNewLine &_
        "Cell Phone: " & aProviderOnDate.CellPhone & vbNewLine &_
        "Alias: " & GetProviderAliasCodeAsText(aProviderOnDate, aAliasCode)
    end if 
  next   
  GetProviderCollectionInfo = aInfo
end function 
 
function GetProviderAliasCodeAsText(aProvider, aAliasCode)  
  set aProviderAlias = aProvider.LoadAlias(aAliasCode)
  aCodeAsText = aProviderAlias.Code & " (Ref1: " & aProviderAlias.Reference1 & ")"  
  GetProviderAliasCodeAsText = aCodeAsText    
end function