ISProviderVers.MemberOfPOS

Example

Display some information about the selected provider version, including the list of places of service the provider is a member of.

sub main()
  Dim aFilter 
  Dim aProviders
  Dim aDate
  Dim aMessage

  Set aFilter = Profile.CreateProvidersFilter
  aFilter.Category = 2 'pcProvider
  aFilter.Code = "VE3"

  set aProviders = Profile.LoadProvidersByFilter(aFilter)

  aDate = #02/20/2020#
  aMessage = GetProviderCollectionInfo(aProviders, aDate)

  Profile.MsgBox(aMessage)
end sub


function GetProviderCollectionInfo(aProviders, aDate)
  Dim aProvider
  Dim aProviderOnDate
  Dim aProvidersMemOfPos, aProviderMemOfPos
  Dim i
  Dim aInfo
   
  aInfo = ""

  for each aProvider in aProviders
    aInfo = aInfo & vbNewLine & vbNewLine & "PROVIDER: " &_
      aProvider.FullName & vbNewLine

    set aProviderOnDate = aProvider.VersionOnDate(aDate)
    if aProviderOnDate is nothing then    
      aInfo = aInfo & vbNewLine & " - " & aProvider.FullName &_
        " (" & aProvider.Id & ") " & "  -  No Version on this date"
    else            
      aInfo = aInfo & vbNewLine & "CURRENT VERSION: " & vbNewLine &_
        "FULL NAME: " & aProvider.FullName & vbNewLine &_
        "ID: " & aProvider.Id & vbNewLine & vbNewLine &_
        "VERSION ON DATE " & aDate & ":  " & vbNewLine &_
        "FULL NAME: " & aProviderOnDate.FullName & vbNewLine &_
        "ID: " & aProviderOnDate.Id & vbNewLine
      
      set aProvidersMemOfPos = aProviderOnDate.MemberOfPOS
      aInfo = aInfo & "MEMBER OF " & aProvidersMemOfPos.Count & " POS/POSes:"
      
      for i = 0 to aProvidersMemOfPos.Count - 1
        set aProviderMemOfPos = aProvidersMemOfPos.Item (i)          
        aInfo = aInfo & vbNewLine & "   - " & aProviderMemOfPos.FullName     
      next ' i  
    end if 
  next ' aProvider 
  GetProviderCollectionInfo = aInfo
end function