ISRecallImmunisation.BatchDiluent

Example

Display some information about the immunisations, including the batch numbers of the stock items used as the diluent for the immunisations.

sub main 
  Dim aPatient
  Dim aRecallPlans, aPlan
  Dim aVisits, aVisit
  Dim aActions, aAction
  Dim aImmunisationAction
  Dim aIndication
  Dim i
  Dim aMessage
     
  Set aPatient = Profile.SelectPatient
  set aRecallPlans = aPatient.RecallPlans
   
  if aRecallPlans.Count = 0 then
    Profile.MsgBox("The patient has no care plans!")
    exit sub
  end if

  for each aPlan in aRecallPlans
    aMessage = aMessage & vbNewLine & "PLAN: '" & aPlan.Description & "'"
    set aVisits = aPlan.Visits
    if aVisits.Count = 0 then
      aMessage = aMessage & vbNewLine & "  NO INTERVENTIONS"
    end if
    for each aVisit in aVisits
      set aActions = aVisit.Actions     
      aMessage = aMessage & vbNewLine & "  INTERVENTION: '" &_
        aVisit.Description & "'  (Action Count = " & aActions.Count & ")"

      for i = 0 to aActions.Count - 1 
        set aAction = aActions.Item(i)
        set aImmunisationAction = aAction.Immunisation
        if aImmunisationAction is nothing then
          aMessage = aMessage & vbNewLine & "-----"
        else        
          aMessage = aMessage & vbNewLine & "   - ACTION: '" & aAction.Description &_
            "'" & vbNewLine &_ 
            "    Batch Diluent: " & aImmunisationAction.BatchDiluent & vbNewLine &_
            "    Batch Diluent Expiry: " & aImmunisationAction.BatchDiluentExpiry & vbNewLine &_
            "    Done Elsewhere: " & aImmunisationAction.DoneElsewhere & vbNewLine &_
            "    Adverse Nature: " & aImmunisationAction.AdverseNature & vbNewLine 
         
          if aImmunisationAction.IndicationId = 0 then
            aMessage = aMessage & "    Indication: NONE" & vbNewLine 
          else
            set aIndication = Profile.LoadShortCode(aImmunisationAction.IndicationId)                  
            aMessage = aMessage & "    Indication: '" & aIndication.Description & "'" & vbNewLine
          end if                                        
        end if    
      next 'i  
    next ' aVisit
  next ' aPlan
  Profile.MsgBox(aMessage)  
end sub