ISRecallObjective.GetProviderInfo

Example

Display the information about the care plan objective that would be useful for a health care provider.

Dim aPatient
Dim aRecallPlans
Dim aMessage
Dim aPlan
Dim i                           
Dim aObjectives
Dim aObjective
Dim aHelpInfo

Set aPatient = Profile.SelectPatient                             
set aRecallPlans = aPatient.RecallPlans

if aRecallPlans.Count = 0 then
  Profile.MsgBox("The patient has no care plans!")
  exit sub
end if                                      

for each aPlan in aRecallPlans
  set aObjectives = aPlan.RecallObjectives
  aMessage = aMessage & "PLAN: '" & aPlan.Description & "'" & vbNewLine 
  
  if aObjectives.Count = 0 then
    aMessage = aMessage & "  NO OBJECTIVES" 
  end if  
         
  for i = 0 to aObjectives.Count - 1
    set aObjective = aObjectives.Item(i)
    aMessage = aMessage & "  Objective Name: '" & aObjective.DisplayName & "'"  
    set aHelpInfo = aObjective.GetProviderInfo
    if aHelpInfo is nothing then
      aMessage = aMessage & vbNewLine & "    No provider info!" & vbNewLine 
    else
      aMessage = aMessage & vbNewLine & "    Provider Info: " &_
        Profile.Rtf2Plain(aHelpInfo.GetBody) & vbNewLine 
    end if    
  next  
next

Profile.MsgBox(aMessage)