ISRecallObjectiveVers.MasterID

Example

Display ID of the most recent version of the care plan objective.

sub main   
  Dim aPatient
  Dim aRecallPlans
  Dim aPlan
  Dim i
  Dim aObjectives
  Dim aObjective
  Dim aObjectiveOnDate
  Dim aMessage
     
  Set aPatient = Profile.SelectPatient
  set aRecallPlans = aPatient.RecallPlans
  aVersionDate = #04/02/2019 12:24#
   
  if aRecallPlans.Count = 0 then
    Profile.MsgBox("The patient has no care plans!")
    exit sub
  end if

  for each aPlan in aRecallPlans
    set aObjectives = aPlan.RecallObjectives
    aMessage = aMessage & vbNewLine & "PLAN: '" & aPlan.Description & "'" & vbNewLine 

    for i = 0 to aObjectives.Count - 1
      set aObjective = aObjectives.Item(i)
      set aObjectiveOnDate = aObjective.VersionOnDate(aVersionDate)
      aMessage = aMessage &_
        MakeObjectiveDescription("    ACTUAL OBJECTIVE VERSION: ", aObjective) &_
        MakeObjectiveDescription("    OBJECTIVE VERSION ON DATE: ", aObjectiveOnDate)
        
    next ' aObjective
  next ' aPlan
  Profile.MsgBox(aMessage)  
end sub 


function MakeObjectiveDescription(aInfo, aObjectiveInstance)
  aMessage = aInfo  
  if aObjectiveInstance is nothing then
    aMessage = aMessage & " UNASSIGNED" 
  else
    aMessage = aMessage & aObjectiveInstance.DisplayName & vbNewLine &_
      "      -Master ID: " & aObjectiveInstance.MasterID     
  end if
  MakeObjectiveDescription = aMessage & vbNewLine
end function