ISRecommendationOverrule.Save

Example

Display some information about overruled recommendations before and after saving the modifications.

sub main

  Dim aTr
  Dim aPatient, aPatientID
  Dim aRecommendationOverrules, aRecommendationOverrule
  Dim aMessage
  Dim i
   
  Set aTr = Profile.StartMapTransaction 
  set aPatient = Profile.SelectPatient
  aPatientID = aPatient.ID 
  set aRecommendationOverrules = Profile.LoadRecommendationOverrules(aPatientID)
    
  aMessage = "Recommendation Overrules Count = " & aRecommendationOverrules.Count &_
    vbNewLine & "Before modification: " & vbNewLine &_
    GetRecommendationsTextInfo(aRecommendationOverrules)
  
  for i = 0 to aRecommendationOverrules.Count - 1
    set aRecommendationOverrule = aRecommendationOverrules.Item(i)
    aRecommendationOverrule.Reason = "Allergic reaction" 
    aRecommendationOverrule.Save
  next    
  aTr.SnapShot   
  
  set aTr = Profile.StartMapTransaction
  
  set aRecommendationOverrules = Profile.LoadRecommendationOverrules(aPatientID)
  
  aMessage = aMessage & vbNewLine & "After modification: " & vbNewLine &_
    GetRecommendationsTextInfo(aRecommendationOverrules) 
    
  Profile.MsgBox(aMessage) 

end sub

function GetRecommendationsTextInfo(aRecommendationOverrules)
  
  Dim aRecommendationOverrule 
  Dim aProvider
  Dim aGuideline
  Dim aMessage
  Dim i  
   
  for i = 0 to aRecommendationOverrules.Count - 1
    set aRecommendationOverrule = aRecommendationOverrules.Item(i)
  
    set aProvider = aRecommendationOverrule.ResponsibleProvider  
    set aGuideline = aRecommendationOverrule.Recommendation.Guideline
  
    aMessage = aMessage & (i + 1) & ") " &_
      "Recommendation Name: " & aRecommendationOverrule.RecommendationName & vbNewLine &_
      "Guideline: " & aGuideline.Name & vbNewLine &_
      "Date: " & aRecommendationOverrule.Date & vbNewLine &_
      "Reason: " & aRecommendationOverrule.Reason & vbNewLine &_
      "Responsible Provider: " & aProvider.Fullname & vbNewLine & vbNewLine  
  next
  GetRecommendationsTextInfo = aMessage  
      
end function