ISRefSeriesPercentile.SeriesVisualProps

Example

Display the number of reference series, the number of sub series and some information about their percentiles, including their visual properties.

sub main
  Dim aReferenceSeriesCollection
  Dim aReferenceSeries
  Dim aRefSeriesSubSeries
  Dim aRefSeriesPercentile
  Dim aSeriesVisualProps   
  Dim aMessage
  Dim i, j, a     

  Set aReferenceSeriesCollection = Profile.GetReferenceSeriesCollection

  aMessage = "Reference Series Count = " & aReferenceSeriesCollection.Count & vbNewLine

  for i = 0 to aReferenceSeriesCollection.Count - 1
    set aReferenceSeries = aReferenceSeriesCollection.Item (i)
    aMessage = aMessage & vbNewLine & (i + 1) & ") " &_
      "Series Name: " & aReferenceSeries.SeriesName & " (" &_
      "SubSeries Count = " & aReferenceSeries.SubSeriesCount & ")" & vbNewLine 
  
    for j = 0 to aReferenceSeries.SubSeriesCount - 1
      set aRefSeriesSubSeries = aReferenceSeries.SubSeries(j)
      aMessage = aMessage  & "-" & (i + 1) & "." & (j + 1) &_
        " Name: " & aRefSeriesSubSeries.Name & " (Percentiles Count = " &_
        aRefSeriesSubSeries.PercentileCount & ")" & vbNewLine
            
      for a = 0 to aRefSeriesSubSeries.PercentileCount - 1
        set aRefSeriesPercentile = aRefSeriesSubSeries.Percentiles(a)
        set aSeriesVisualProps = aRefSeriesPercentile.SeriesVisualProps  
            
        aMessage = aMessage & (i + 1) & "." & (j + 1) & "." & (a + 1) & ". " &_
          "Percentile Name: " & aRefSeriesPercentile.Name & vbNewLine &_
          "          Order: " & aRefSeriesPercentile.Order & vbNewLine &_
          "          Series Visual Props (Visible): " &_
          aSeriesVisualProps.Visible & vbNewLine &_
          "          Series Visual Props (Pen Style): " &_
          GetPenStyleDescr(aSeriesVisualProps.VisualProps.PenStyle) & vbNewLine   
      next 'a  
    next 'j        
  next 'i 

  Profile.MsgBox(aMessage)
end sub

function GetPenStyleDescr(aPenStyle)
  Dim aResult

  Select Case aPenStyle
    Case 0
      aResult = "Solid"
    Case 1
      aResult = "Dash"
    Case 2
      aResult = "Dot"
    Case 3
      aResult = "Dash-Dot"
    Case 4
      aResult = "Dash-Dot-Dot"
    Case 5
      aResult = "Clear"
    Case 6
      aResult = "Inside Frame"
  End Select
  
  GetPenStyleDescr = aResult
end function