ISReferenceSeries.PatientSeriesVisualProps

Example

Display the number of reference series and some information about them, including the visual properties of their patient series.

sub main
  Dim aReferenceSeriesCollection
  Dim aReferenceSeries
  Dim aMainSeriesVisualProps
  Dim aPatientSeriesVisualProps  
  Dim aMessage
  Dim i   

  Set aReferenceSeriesCollection = Profile.GetReferenceSeriesCollection

  aMessage = "Reference Series Count = " & aReferenceSeriesCollection.Count & vbNewLine

  for i = 0 to aReferenceSeriesCollection.Count - 1
    set aReferenceSeries = aReferenceSeriesCollection.Item(i)
    
    set aMainSeriesVisualProps = aReferenceSeries.MainSeriesVisualProps
    set aPatientSeriesVisualProps = aReferenceSeries.PatientSeriesVisualProps
     
    aMessage = aMessage & vbNewLine & (i + 1) & ". " &_
      "Series Name: " & aReferenceSeries.SeriesName & vbNewLine &_
      "-Comment: " & aReferenceSeries.Comment & vbNewLine &_
      "-ID: " & aReferenceSeries.ID & vbNewLine &_   
      "-Main Series Visual Props (Visible): " &_
      aMainSeriesVisualProps.Visible & vbNewLine &_
      "-Main Series Visual Props (Pen Style): " &_
      GetPenStyleDescr(aMainSeriesVisualProps.VisualProps.PenStyle) & vbNewLine &_
      "-Patient Series Visual Props (Visible): " &_
      aPatientSeriesVisualProps.Visible & vbNewLine &_
      "-Patient Series Visual Props (Pen Style): " &_
      GetPenStyleDescr(aPatientSeriesVisualProps.VisualProps.PenStyle) & vbNewLine   
  next

  Profile.MsgBox(aMessage)  
end sub

function GetPenStyleDescr(aPenStyle)
  Dim aResult

  Select Case aPenStyle
    Case 0
      aResult = "Solid"
    Case 1
      aResult = "Dash"
    Case 2
      aResult = "Dot"
    Case 3
      aResult = "Dash-Dot"
    Case 4
      aResult = "Dash-Dot-Dot"
    Case 5
      aResult = "Clear"
    Case 6
      aResult = "Inside Frame"
  End Select
  
  GetPenStyleDescr = aResult
end function