ISReferral.UnlinkDocument

Example

Unlink the document from the referral of the selected patient.

sub main
  Dim aPatient
  Dim aFilter
  Dim aReferrals, aReferral
  Dim aDocuments, aDocument
  Dim aMessage

  Set aPatient = Profile.SelectPatient
  set aFilter = Profile.CreateReferralsFilter
  aFilter.Patient = aPatient
  set aReferrals = Profile.LoadReferrals(aFilter)

  aMessage = "INITIAL STATE:" & GetLinkedResultsInfo(aReferrals)

  set aFilter = Profile.CreateCDOTransFilter
  aFilter.PatientId = aPatient.Id
  aFilter.TransactionTypes = 64 ' tsotweScannedDocs 
  set aDocuments = Profile.LoadCDOTransactions(aFilter)
    
  for each aReferral in aReferrals 
    for each aDocument in aDocuments
      if aDocument.FilingCategory = 6 or aDocument.FilingCategory = 8 then 'scfcScannedDocument  or scfcLetter  
        aReferral.UnLinkDocument aDocument
      end if  
    next
  next
  aMessage = aMessage & vbNewLine & vbNewLine &_ 
    "REFERRALS AFTER DOCUMENTS UNLINKING:" & GetLinkedResultsInfo(aReferrals) & vbNewLine

  Profile.MsgBox(aMessage)
end sub

function GetLinkedResultsInfo(aReferrals)
  Dim aReferral
  Dim aInfo
  Dim aDocuments, aDocument
  
  aInfo = ""
  for each aReferral in aReferrals
    aInfo = aInfo & vbNewLine & "Referral Id: " & aReferral.Id
    set aDocuments = aReferral.LinkedDocuments
    if aDocuments.Count > 0 then aInfo = aInfo & vbNewLine & "  Documents IDs: "   
    for each aDocument in aDocuments
      aInfo = aInfo & aDocument.Id & ", "
    next
  next
  GetLinkedResultsInfo = aInfo
end function