ISServiceRates.Item

Description

Each of the service rates within the collection.

Syntax

object.Item(aIndex)

Part	Attribute	Type	Description
`object`	Required	ISServiceRates	The `object` always implements the ISServiceRates interface
`aIndex`	In, Required	int	The index of the service rate

Restriction: This property is readonly.

Return Value

ISServiceRate

Example

Display some information about service rates.

Dim aFilter
Dim aServices
Dim aService
Dim aMessage
Dim aServicePrices
Dim aServicePrice
Dim aRates
Dim aRate
Dim i, j, k

Set aFilter = Profile.CreateServicesFilter
aFilter.Description = "Pinch Skin Graft"

set aServices = Profile.LoadServicesByFilter(aFilter)

aMessage = "Services Count = " & aServices.Count & vbNewLine

for i = 0 to aServices.Count - 1
  set aService = aServices.Item(i)

  set aServicePrices = aService.GetServicePrices

  aMessage = aMessage & vbNewLine & aService.Description &_
    " has " & aServicePrices.Count & " service prices"

  for j = 0 to aServicePrices.Count - 1
    set aServicePrice = aServicePrices.Item (j)
    set aRates = aServicePrice.GetRates 
   
    aMessage = aMessage & vbNewLine & "  Service Rates Count: " & aRates.Count
    for k = 0 to aRates.Count - 1
       set aRate = aRates.Item(k) 
       aMessage = aMessage & vbNewLine & "    Rate Amount: " & aRate.Amount &_
         "; rate type: " & aRate.RateType.Code 
    next 'k
  next 'j
next 'i

Profile.MsgBox(aMessage)

Note:

In Profile Client v8 on User Interface Rates can be found in Maintain > Services > Edit the selected service > Financial > Charge Rates.

Version information

Added in v8.3.0