ISSourceFolder.CreateBy

Example

Create new folders with the specified paths and display some information about the selected folder.

sub main
  Dim aStore
  Dim aPath  
  Dim aFolder
  Dim aMessage
   
  set aStore = Profile.SourceStore
  EnsureFolder aStore, "Examples"
  EnsureFolder aStore, "Examples/Part1"
  EnsureFolder aStore, "Examples/Part2"  
 
  aPath = InputBox("Enter folder path:", "Folder search")
  if aPath = "" then
    Profile.MsgBox("No folder path was entered")
    exit sub
  end if
  
  
  on error resume next 
  set aFolder = aStore.GetFolder(aPath)
  if Err.Number <> 0 Then
    Err.Clear  
    Profile.MsgBox("There is no folder with path '" & aPath & "'")
    exit sub
  end if   
   
 
  aMessage = "Folder information: " & vbNewLine & vbNewLine &_
    "Folder Name: " & aFolder.FolderName & vbNewLine &_
    "Full Path: " & aFolder.FullPath & vbNewLine &_
    "Create By: " & aFolder.CreateBy & vbNewLine &_
    "Folder Date: " & aFolder.FolderDate        

  Profile.MsgBox(aMessage)
end sub

    
sub EnsureFolder(aStore, aFolderName)
  Dim aFolder

  on error resume next 
  set aFolder = aStore.GetFolder(aFolderName)
  if Err.Number <> 0 Then
    Err.Clear  
    set aFolder = aStore.CreateFolder(aFolderName)
    Profile.MsgBox("The folder '" & aFolder.FullPath & "' was created")
  end if  
end sub