ISWhiteboardItem.AddedDT

Example

Display the number of the whiteboard items loaded on the basis of the selected filter, some information about them, including the dates and time the whiteboard entries were added.

sub main
  Dim aPatient
  Dim aFilter
  Dim aWhiteboardItems
  Dim aWhiteboardItem
  Dim aMessage
  Dim i

  Set aPatient = Profile.SelectPatient
  set aFilter = Profile.CreateWhiteboardFilter
  aFilter.PatientId = aPatient.Id
  set aWhiteboardItems = Profile.LoadWhiteboardItems(aFilter)
  aMessage = "Whiteboard Items Count = " & aWhiteboardItems.Count

  for i = 0 to aWhiteboardItems.Count - 1
    set aWhiteboardItem = aWhiteboardItems.Item(i)
    aMessage = aMessage & vbNewLine & " ---------------------- " & vbNewLine &_
       "Acuity: " & aWhiteboardItem.AcuityTypeCode & vbNewLine &_
       "Added : " & aWhiteboardItem.AddedDT & vbNewLine &_ 
       "Reason: " & aWhiteboardItem.ReasonTypeCode & vbNewLine &_       
       "Instruction: " & aWhiteboardItem.Instruction & vbNewLine &_  
       "Board: " & aWhiteboardItem.BoardTypeCode & vbNewLine &_
       "From POS: " & GetProviderNameById(aWhiteboardItem.FromPosID) & vbNewLine &_  
       "From Provider: " & GetProviderNameById(aWhiteboardItem.FromProviderID) & vbNewLine &_
       "To POS: " & GetProviderNameById(aWhiteboardItem.ToPOSID) & vbNewLine &_ 
       "To Provider: " & GetProviderNameById(aWhiteboardItem.ToProviderID) & vbNewLine
  next

  Profile.MsgBox(aMessage)
end sub    

function GetProviderNameById(aProviderId)
  Dim aName
  Dim aProvider
  
  if aProviderId = 0 then
    aName = " - "
  else
    set aProvider = Profile.LoadProviderById(aProviderId)
    aName = aProvider.FullName    
  end if
  
  GetProviderNameById = aName           
end function